Frase Célebre de Nikola Tesla

La ciencia no es sino una perversión de si misma
a menos que tenga como objetivo final 
el mejoramiento de la humanidad

Nikola Tesla

Gráficas a partir del comando AnglePath

Descargar como Notebook

Desde la versión 11.1 de Mathematica aparece dentro de la lista de comandos el comando AnglePath, con la sintaxis

Da la lista de coordenadas 2 D correspondientes al camino que comienza en {0,0} y avanza tomando pasos de una unidad con un ángulo θⱼ

Ahora, cada paso tiene una longitud de rⱼ

Por ejemplo

AnglePath[{90 Degree, 90 Degree, 90 Degree}]
{{0, 0}, {0, 1}, {-1, 1}, {-1, 0}}

Graficando la línea que une los puntos

Otras Gráficas

Graphics[Line[AnglePath[ConstantArray[110 Degree, 20]]]]

Graphics[Line[AnglePath[Range[0, 100, .01]]]]

Graphics[Line[AnglePath[N@Range[100000]]]]

Graphics[Line[
  AnglePath /@ 
   Table[{0.666^i, RandomChoice[{-Pi/3, Pi/8}]}, {10}, {i, 10}]]]

Graphics[BSplineCurve[
  Map[AnglePath[Transpose[{0.666^Range[10], #}]] &, 
   Tuples[{-Pi/3, Pi/8}, 10]]]]

Graphics@Line[
  AnglePath[
   Nest[Flatten[{1, -2, 1, #} & /@ #] &, {1, 1, 1, 1, 1}, 4] 2 Pi/5]]

A partir de una función predefinida

rot[theta_, dr_] := 
 Graphics[Line[AnglePath[Table[{r,theta}, {r, 0, 1, dr}]]]]

rot[45.2 Degree, 0.01]

rot[102.7 Degree, 0.005]

rot[119.4 Degree, 0.01]

Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas

Frase Célebre de Stephen Hawking

Uno no puede discutir con un Teorema matemático

Stephen Hawking

Cantidad de letras en una lista de números

Descargar como Notebook

Dada la lista de los cinco primeros números en letras, tendríamos :

                                 {uno, dos, tres, cuatro, cinco}

que contiene 3+3+4+6+5 = 21 letras en total.


¿Cuál es la cantidad de letras que tiene la lista de los primeros mil números enteros positivos?

Para esto utilizamos el comando IntegerName[ ], con la característica "Spanish"

Length@Flatten@
  Characters@
   StringReplace[IntegerName[Range[1000], "Spanish"], 
    Whitespace -> ""]

20021

Así, en total la lista de los primeros mil enteros positivos escritos en letras tiene 20021 caracteres.

Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas

Frase Célebre de Marcus du Sautoy

Quien domine las matemáticas
dominará el mundo

 Marcus du Sautoy

Día de Pi: Marzo 14 (3-14)

Descargar como Notebook

Se ha institucionalizado el día 14 de Marzo como el Día de Pi (ver anterior homenaje), bueno, realmente sería el día de la aproximación de Pi. Por eso, voy a realizar el homenaje a Pi con siete curiosas aproximaciones del número Pi.

Simplemente para comparar nuestros resultados, tenemos Pi expresado con sus primeras cien cifras decimales:

N[Pi, 100]
3.141592653589793238462643383279502884197169399375105820974944592307816406286208998628034825342117068

Primera

Calculando el seno en grados sexagesimales del inverso multiplicativo de un número compuesto por cincos

N[Sin[1/5555555555 Degree], 100]
3.141592653903952503853033465952025147279786503027734180372294146978528388029605422413805437525142862*10^-12

¿Cuál será la razón?

Segunda

Al calcular :

N[163 (Pi - E), 5]
69.000

Por tanto :

N[69/163 + E]
3.14159

Tercera

Al calcular :

2.000

Por tanto :

3.14138

Cuarta

Al calcular :

N[Pi^4 + Pi^5, 8] == N[E^6, 8]
True

Por tanto, una de las soluciones de :

NSolve[x^5 + x^4 == E^6, x]
{{x -> -2.90631 - 1.93429 I}, {x -> -2.90631 + 1.93429 I}, {x -> 
   0.835513 - 3.13657 I}, {x -> 0.835513 + 3.13657 I}, {x -> 3.14159}}

en este caso la quinta solución, la solución real:

x /. NSolve[x^5 + x^4 == E^6, x][[5]]
3.14159

Quinta

Al calcular :

N[E^Pi - Pi, 4]
20.00

Por tanto :

N[Log[20 + Pi]]
3.14163

Sexta

Se debe al Matemático Indio Ramanujan

3.141592653


Séptima

Si se toma la suma hasta infinito se tiene la igualdad,

pero me parece curiosa pues intervienen los números de Fibonacci, así que tomando la aproximación


N[4 Sum[ArcTan[1/Fibonacci[2 n + 1]], {n, 100}], 10]
3.141592654


Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas

Frase Célebre de autor Anónimo

El mejor profesor 
no es el que más sabe 
ni el que más explica, 
sino aquel con el que los alumnos más aprenden...

Anónimo

Ecuaciones Diferenciales de Primer Orden

Descargar como Notebook

Las EDO (Ecuaciones Diferenciales Ordinarias) de primer Orden, las podemos escribir como:

es decir, como la derivada igual a una función que depende de la variable (x) y la incógnita (y).

Interpretación Geométrica

De Cálculo Diferencial sabemos que la derivada la interpretamos como: Pendiente de la recta tangente en un punto. Así, para cada punto en el plano (x,y) la función f(x,y) nos indica la pendiente de la recta tangente de alguna curva solución que por allí pase.

Campos de Pendientes

De acuerdo a la anterior interpretación, podemos en cada punto trazar un pequeño segmento que tenga la pendiente que nos indica la función f(x,y).

Comandos de Mathematica

Con los comandos VectorPlot[ ] y StreamPlot[ ] podemos representar los campos de pendientes

f[x_, y_] := x - 2 y
VectorPlot[{1, f[x, y]}, {x, -5, 5}, {y, -10, 10}]

StreamPlot[{1, f[x, y]}, {x, -5, 5}, {y, -10, 10}]

y mejorando la forma y tamaño de las flechas

VectorPlot[{1, f[x, y]}, {x, -5, 5}, {y, -10, 10}, Axes -> True, 
 Frame -> False, VectorScale -> {Tiny, Tiny, None}, 
 ImageSize -> Large]

Soluciones Analíticas

Mathematica resuelve EDO de forma analítica por medio del comando DSolve[ ], veamos:

Ejemplo :

Resolver la ecuación diferencial

DSolve[y'[x] + 2 y[x] == x, y[x], x]

sol = y[x] /. DSolve[{y'[x] + 2 y[x] == x, y[0] == 1}, y[x], x][[1]]

Graficando junto al campo de pendientes

g1 = VectorPlot[{1, f[x, y]}, {x, -5, 5}, {y, -10, 10}, Axes -> True, 
  Frame -> False, VectorScale -> {Tiny, Tiny, None}, 
  ImageSize -> Large]

g2 = Plot[sol, {x, -6, 6}, PlotStyle -> Red];
Show[g1, g2]

Clear[y, x, h, a, b]
plot1 = VectorPlot[{1, f[x, y]}, {x, -5, 5}, {y, -10, 10}, 
   Axes -> True, Frame -> False, VectorScale -> {Tiny, Tiny, None}, 
   ImageSize -> 250];
sola = DSolve[{y'[x] == f[x, y[x]], y[a] == b}, y[x], x];
h[x_, a_, b_] = Simplify[sola[[1, 1, 2]]];
plot3 = Plot[
   Evaluate[Table[h[x, a, b], {a, -3, 3, 2}, {b, -3, 3, 2}]], {x, -5, 
    5}, PlotRange -> {-10, 10}];
Show[plot1, plot3, ImageSize -> 250]

Mediante un Manipulate

Manipulate[
 Show[g1, Plot[
   Evaluate[
    y[x] /. DSolve[{y'[x] + 2 y[x] == x, y[a] == b}, y[x], x][[
      1]]], {x, -6, 6}, PlotStyle -> Red],(*Plot[1/2x-1/4,{x,-5,5}],*)
  Graphics[{PointSize[Large], Point[{a, b}]}]], {{a, 0}, -5, 
  5}, {{b, 0}, -5, 5}]

Otro Ejemplo

La ecuación diferencial

DSolve[y'[x] == y[x]^2 - 4, y[x], x]

Manipulate[
 Show[VectorPlot[{1, y^2 - 4}, {x, -5, 5}, {y, -6, 6}, Axes -> True, 
   Frame -> False, VectorScale -> {Tiny, Tiny, None}, 
   ImageSize -> 250], 
  Plot[{-2, 
    2, -((2 (2 + c - 2 E^(4 x) + c E^(4 x)))/(-2 - c - 2 E^(4 x) + 
      c E^(4 x)))}, {x, -5, 5}, PlotStyle -> {LightBlue, Green, Red}, 
   Exclusions -> {-2 - c - 2 E^(4 x) + c E^(4 x) == 0}]], {{c, 
   0}, -10, 10}]

Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas

Frase Célebre de Karl Pearson

El matemático que se encuentra bajo su diluvio de símbolos, 
y trabaja al parecer con verdades puramente formales, 
puede aún alcanzar resultados de infinita importancia 
para la descripción de nuestro mundo físico.

Karl Pearson